all repos — openbox @ 41bdbec9c6468c5024d21500efd381bba46ad72f

openbox fork - make it a bit more like ryudo

configure.ac (raw)

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
AC_INIT([src/main.cc])
AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE([openbox], [2.90.0cvs])

AC_PREREQ([2.50])

AC_PATH_PROG([regex_cmd], [sed])
test "$regex_cmd" || AC_MSG_ERROR([sed not found])

AC_PROG_CC
AC_PROG_CXX
AC_PROG_LIBTOOL
LIBTOOL="$LIBTOOL --silent"
AC_PROG_INSTALL

ALL_LINGUAS=""
AM_GNU_GETTEXT

AC_LANG(C++)
	
# Check what compiler we are using
AC_MSG_CHECKING([for GCC])
if test "$GCC" = "yes"; then
  AC_MSG_RESULT([yes])
  CXXFLAGS="$CXXFLAGS -Wall -W -pedantic"
else
  AC_MSG_RESULT([no, trying other compilers])
  AC_MSG_CHECKING(for MIPSpro)
  mips_pro_ver=`$CXX -version 2>&1 | grep -i mipspro | cut -f4 -d ' '`
  if test -z "$mips_pro_ver"; then
    AC_MSG_RESULT([no])
  else
    AC_MSG_RESULT([yes, version $mips_pro_ver.])
    AC_MSG_CHECKING(for -LANG:std in CXXFLAGS)
    lang_std_not_set=`echo $CXXFLAGS | grep "\-LANG:std"`
    if test "x$lang_std_not_set" = "x"; then
      AC_MSG_RESULT([not set, setting.])
      CXXFLAGS="${CXXFLAGS} -LANG:std"
    else
      AC_MSG_RESULT([already set.])
    fi
  fi
fi

# Determine if maintainer portions of the Makefiles should be included.
AM_MAINTAINER_MODE

# Check for system header files
AC_CHECK_HEADERS(ctype.h dirent.h fcntl.h libgen.h locale.h nl_types.h process.h signal.h stdarg.h stdio.h stdlib.h string.h time.h unistd.h sys/param.h sys/select.h sys/signal.h sys/stat.h sys/time.h sys/types.h sys/wait.h)
AC_HEADER_TIME

# Determine the return type of signal handlers
AC_TYPE_SIGNAL

# Check whether to include debugging code
DEBUG=""
AC_MSG_CHECKING([whether to include verbose debugging code])
AC_ARG_ENABLE([debug],
  [  --enable-debug          include verbose debugging code @<:@default=no@:>@],
  if test "$enableval" = "yes"; then
    AC_MSG_RESULT([yes])
    if test "$GCC" = "yes"; then
       DEBUG="-DDEBUG -fno-inline -g"
    else
       DEBUG="-DDEBUG"
    fi
  else
    AC_MSG_RESULT([no])
    DEBUG="-DNDEBUG"
  fi,
  AC_MSG_RESULT([no])
  DEBUG="-DNDEBUG"
)
CXXFLAGS="$CXXFLAGS $DEBUG"

# Check for Python
AC_ARG_WITH([python],
	[  --with-python=path       Set location of Python executable],
	[PYTHON="$withval"],
	[PYTHON=])

# Find the python bin
if ! test "$PYTHON"; then
  AC_CHECK_PROGS(PYTHON, $prefix/bin/python python python2.4 python2.3 python2.2 python2.1 python2.0 python1.6 python1.5 python1.4)
fi
if ! test "$PYTHON"; then
   AC_MSG_ERROR([Openbox requires the use of Python. This is its secret special formula for extreme sexiness.
See http://www.python.org
])
fi

# Find our python paths
AC_MSG_CHECKING([for Python version])
# Need to do this hack since autoconf replaces __file__ with the name of the configure file
filehack="file__"
PYVERSION=`($PYTHON -c "import string,operator; print operator.getitem(string.split(string.__$filehack,'/'),-2)")`
AC_MSG_RESULT([$PYVERSION])

AC_MSG_CHECKING([for Python prefix])
PYPREFIX=`($PYTHON -c "import sys; print sys.prefix") 2>/dev/null`
AC_MSG_RESULT([$PYPREFIX])
AC_MSG_CHECKING([for Python exec-prefix])
PYEPREFIX=`($PYTHON -c "import sys; print sys.exec_prefix") 2>/dev/null`
AC_MSG_RESULT([$PYEPREFIX])

# Find the include directory
AC_MSG_CHECKING([for Python header files])
if test -r "$PYPREFIX/include/$PYVERSION/Python.h"; then
  PYTHON_CFLAGS="-I$PYPREFIX/include/$PYVERSION"
fi
if test -z "$PYTHON_CFLAGS"; then
  if test -r "$PYPREFIX/include/Py/Python.h"; then
    PYTHON_CFLAGS="-I$PYPREFIX/include/Py"
  fi
fi
if ! test "$PYTHON_CFLAGS"; then
  AC_MSG_ERROR([Not found])
else
  AC_MSG_RESULT([$PYTHON_CFLAGS])
fi

# Set the library directory blindly.   This probably won't work with older versions
AC_MSG_CHECKING([for Python library])
dirs="$PYVERSION/config $PYVERSION/lib python/lib"
for i in $dirs; do
  if test -d "$PYEPREFIX/lib/$i"; then
    PYLIB="$PYEPREFIX/lib/$i"
    break
  fi
done
if ! test "$PYLIB"; then
  AC_MSG_ERROR([Not found])
else
  AC_MSG_RESULT([$PYLIB])
fi

# Check for really old versions
if test -r "$PYLIB/libPython.a"; then
    PYTHON_LIBS="-L$PYLIB -lModules -lPython -lObjects -lParser"
else
    PYTHON_LIBS="-L$PYLIB -l$PYVERSION"
fi

AC_SUBST([PYTHON_CFLAGS])
AC_SUBST([PYTHON_LIBS])

# Check for X headers and libraries
AC_PATH_X
AC_PATH_XTRA
test "$no_x" = "yes" && AC_MSG_ERROR([No Xlibs found.])
test -z "$x_includes" && x_includes="/usr/include"
test -z "$x_libraries" && x_libraries="/usr/lib"
     
CXXFLAGS="$CXXFLAGS $X_CFLAGS"
LIBS="$LIBS $X_LIBS $X_EXTRA_LIBS"
LDFLAGS="$LDFLAGS $X_PRE_LIBS $LIBS $X_EXTRA_LIBS"

# Check for required functions in -lX11
AC_CHECK_LIB([X11], [XOpenDisplay],
  ,
  AC_MSG_ERROR([Could not find XOpenDisplay in -lX11.])
)


# Check for Xft >= 2
XFT_MIN_MAJOR=2
XFT_MIN_MINOR=0
XFT_MIN_REVISION=0
XFT_MIN=$XFT_MIN_MAJOR.$XFT_MIN_MINOR.$XFT_MIN_REVISION
AC_MSG_CHECKING([for Xft version >= $XFT_MIN])
if ! pkg-config --atleast-version $XFT_MIN xft; then
  AC_MSG_RESULT([no])
  AC_MSG_ERROR([Openbox requires the Xft version >= $XFT_MIN font library.
See http://www.fontconfig.org/
])
fi

AC_MSG_RESULT([yes])

# Store these
OLDLIBS=$LIBS
OLDCXXFLAGS=$CXXFLAGS

XFT_CFLAGS="`pkg-config --cflags xft`"
XFT_LIBS="`pkg-config --libs xft`"

# Set these for checking with the tests below. They'll be restored after
LIBS="$LIBS $XFT_LIBS"
CXXFLAGS="$XFT_CFLAGS $CXXFLAGS"

AC_CHECK_LIB([Xft], [XftFontOpenName],
  AC_MSG_CHECKING([for X11/Xft/Xft.h for Xft >= $XFT_MIN])
  AC_TRY_COMPILE(
    [
      #include <X11/Xlib.h>
      #include <X11/Xft/Xft.h>
    ],
    [
      #if !defined(XFT_MAJOR)
      # error Xft.h is too old
      #endif
      #if XFT_MAJOR < $XFT_MIN_MAJOR
      # error Xft.h is too old
      #endif
      #if XFT_MAJOR == $XFT_MIN_MAJOR
      # if XFT_MINOR < $XFT_MIN_MINOR
      #  error Xft.h is too old
      # endif
      #endif
      #if XFT_MAJOR == $XFT_MIN_MAJOR
      # if XFT_MAJOR == $XFT_MIN_MINOR
      #  if XFT_REVISION < $XFT_MIN_REVISION
      #   error Xft.h is too old
      #  endif
      # endif
      #endif
      
      int i = XFT_MAJOR;
      XftFont foo;
    ],
    [
      AC_MSG_RESULT([yes])
    ],
    [
      AC_MSG_RESULT([no])
      AC_MSG_ERROR([Openbox requires the Xft version >= $XFT_MIN font library.
See http://www.fontconfig.org/
])
    ]
  )

  AC_MSG_CHECKING([if we can compile with Xft])
  AC_TRY_LINK(
    [
      #include <X11/Xlib.h>
      #include <X11/Xft/Xft.h>
    ],
    [
      int i = XFT_MAJOR;
      XftFont foo
    ],
    [
      AC_MSG_RESULT([yes])
    ],
    [ 
      AC_MSG_RESULT([no])
      AC_MSG_ERROR([Unable to compile with the Xft library.
])
    ]
  )
)
# Restore the old values. Use XFT_CFLAGS and XFT_LIBS in the Makefile.am's
LIBS=$OLDLIBS
CXXFLAGS=$OLDCXXFLAGS

AC_SUBST([XFT_CFLAGS])
AC_SUBST([XFT_LIBS])

# Check for XShape extension support
AC_CHECK_LIB([Xext], [XShapeCombineShape],
  AC_MSG_CHECKING([for X11/extensions/shape.h])
  AC_TRY_LINK(
    [
      #include <X11/Xlib.h>
      #include <X11/Xutil.h>
      #include <X11/extensions/shape.h>
    ],
    [
      long foo = ShapeSet
    ],
    [
      AC_MSG_RESULT([yes])
      SHAPE="yes"
      AC_DEFINE([SHAPE], [1], [Found the XShape extension])
      LIBS="$LIBS -lXext"
    ],
    [ 
      AC_MSG_RESULT([no])
      SHAPE="no"
    ]
  )
)
AC_MSG_CHECKING([for the XShape extension])
if test "$SHAPE" = "yes"; then
  AC_MSG_RESULT([yes])
else
  AC_MSG_RESULT([no])
fi

# Check for Xinerama extension support
AC_MSG_CHECKING([whether to build support for the Xinerama extension])
XINERAMA="no"
AC_ARG_ENABLE([xinerama],
[  --enable-xinerama       enable support of the Xinerama extension @<:@default=no@:>@],
  if test "$enableval" = "yes"; then
	AC_MSG_RESULT([yes])

	AC_CHECK_LIB([Xinerama], [XineramaQueryExtension],
	  [
	    AC_MSG_CHECKING([for X11/extensions/Xinerama.h])
	    AC_TRY_LINK(
	      [
                #include <X11/Xlib.h>
                #include <X11/extensions/Xinerama.h>
	      ],
	      [
                XineramaScreenInfo foo
	      ],
	      [
	        AC_MSG_RESULT([yes])
	        XINERAMA="yes"
	        AC_DEFINE([XINERAMA], [1],
	                  [Enable support of the Xinerama extension])
	        LIBS="$LIBS -lXinerama"
	      ],
	      [
	        AC_MSG_RESULT([no])
	      ]
	    )
	  ]
	)

    AC_MSG_CHECKING([for the Xinerama extension])
    if test "$XINRERAMA" = "yes"; then
      AC_MSG_RESULT([yes])
    else
      AC_MSG_RESULT([no])
    fi
  else
	AC_MSG_RESULT([no])
  fi,
  AC_MSG_RESULT([no])
)

AC_CONFIG_FILES([Makefile
		m4/Makefile 
		po/Makefile.in
		intl/Makefile
		otk/Makefile
		src/Makefile
		scripts/Makefile
		util/Makefile
		util/epist/Makefile
		doc/Makefile
		doc/doxygen/Makefile
		data/Makefile
		data/styles/Makefile
		version.h
		])
AC_OUTPUT

AC_MSG_RESULT
AC_MSG_RESULT([$PACKAGE version $VERSION configured successfully.])

AC_MSG_RESULT
AC_MSG_RESULT([Using '$prefix' for installation.])
AC_MSG_RESULT([Using '$CXX' for C++ compiler.])
AC_MSG_RESULT([Building with '$CXXFLAGS' for C++ compiler flags.])
AC_MSG_RESULT([Building with '$LIBS' for linker flags.])
AC_MSG_RESULT
AC_MSG_RESULT([configure complete, now type \"make\"])
AC_MSG_RESULT